#! /usr/bin/awk -f 

###
### TOPXML.AWK
### (c) 2003 Software Poetry
### http://www.softwarepoetry.com/webob
###
### Takes batch output from "top" and turns it into xml on stdout:
###		
###		top -b -n1 | topxml.awk			
###		top -b -n1 -p PID | topxml.awk
###		top -b -n1 `cat /home/webob/webob.pid` | topxml.awk	
###

BEGIN	{
		fInProcs = 0;
		print "<topxml>";
		}

END		{
		print "\t</procs>\n</topxml>";
		}

($1 == "CPU")	\
		{
		gsub(/\%/, "");
		printf("\t<cpu>\n\t\t<user>%s</user>\n", $3);
		printf("\t\t<system>%s</system>\n", $5);
		printf("\t\t<nice>%s</nice>\n", $7);
		printf("\t\t<idle>%s</idle>\n\t</cpu>\n", $9);
		}

($1 == "Mem:")	\
		{
		gsub(/K/, "");
		printf("\t<memory>\n\t\t<available>%s</available>\n", $2);
		printf("\t\t<used>%s</used>\n", $4);
		printf("\t\t<free>%s</free>\n\t</memory>\n", $6);
		}

($1 == "Swap:")	\
		{
		gsub(/K/, "");
		printf("\t<swap>\n\t\t<available>%s</available>\n", $2);
		printf("\t\t<used>%s</used>\n", $4);
		printf("\t\t<free>%s</free>\n\t</swap>\n", $6);
		}

($1 == "PID")	\
		{
		fInProcs = 1;
		print "\t<procs>";

		gsub(/\%/, "");
		for (i = 1; i <= NF; ++i)
			rgszNames[i] = tolower($i);

		next;
		}


		{
		if (fInProcs)
			{
			print "\t\t<proc>";

			gsub(/\r/, "");
			gsub(/\&/, "\\&amp;");
			gsub(/</, "\\&lt;");
			gsub(/>/, "\\&gt;");
			gsub(/\"/, "\\&quot;");

			for (i = 1; i <= NF; ++i)
				printf("\t\t\t<%s>%s</%s>\n", rgszNames[i], $i, rgszNames[i]);

			print "\t\t</proc>";
			}		
		}